if vk_dep.found()
  platform_defs = []
  if get_option('use_xlib')
    platform_defs = ['-DVK_USE_PLATFORM_XLIB_KHR']
  elif host_machine.system() == 'windows'
    platform_defs = ['-DVK_USE_PLATFORM_WIN32_KHR']
  endif

  vk_inc_dep = vk_dep.partial_dependency(compile_args : true, includes : true)
  vk_renderer_lib = library('rtvk',
    # Project Sources
    'command_buffers.h',
    'gpu.h',
    'gpu_sync.h',
    'pipelines.h',
    'render_targets.h',
    'swapchain.h',

    'command_buffers.c',
    'frame.c',
    'gpu_sync.c',
    'helper.c',
    'init.c',
    'pipelines.c',
    'render_targets.c',
    'swapchain.c',

    # Contrib Sources
    contrib_dir / 'volk/volk.h',
    contrib_dir / 'volk/volk.c',
    contrib_dir / 'vma/vk_mem_alloc.h',
   'vma_impl.cpp',
    dependencies : [m_dep, vk_inc_dep, windowing_dep],
    include_directories : [engine_incdir, include_directories(contrib_dir)],
    link_with : [runtime_lib],
    c_pch : 'pch/vk_pch.h',
    c_args : platform_defs,
    cpp_pch : 'pch/vk_pch.h',
    cpp_args : platform_defs,
    install : true)

    engine_libs = vk_renderer_lib
    engine_lib_paths += vk_renderer_lib.full_path()
endif